u-boot.lds 1.6 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102
  1. /*
  2. * Copyright (c) 2004-2008 Texas Instruments
  3. *
  4. * (C) Copyright 2002
  5. * Gary Jennejohn, DENX Software Engineering, <garyj@denx.de>
  6. *
  7. * SPDX-License-Identifier: GPL-2.0+
  8. */
  9. OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
  10. OUTPUT_ARCH(arm)
  11. ENTRY(_start)
  12. SECTIONS
  13. {
  14. . = 0x00000000;
  15. . = ALIGN(4);
  16. .text :
  17. {
  18. *(.__image_copy_start)
  19. CPUDIR/start.o (.text*)
  20. *(.text*)
  21. }
  22. . = ALIGN(4);
  23. .rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }
  24. . = ALIGN(4);
  25. .data : {
  26. *(.data*)
  27. }
  28. . = ALIGN(4);
  29. . = .;
  30. . = ALIGN(4);
  31. .u_boot_list : {
  32. KEEP(*(SORT(.u_boot_list*)));
  33. }
  34. . = ALIGN(4);
  35. .image_copy_end :
  36. {
  37. *(.__image_copy_end)
  38. }
  39. .rel_dyn_start :
  40. {
  41. *(.__rel_dyn_start)
  42. }
  43. .rel.dyn : {
  44. *(.rel*)
  45. }
  46. .rel_dyn_end :
  47. {
  48. *(.__rel_dyn_end)
  49. }
  50. _end = .;
  51. /*
  52. * Deprecated: this MMU section is used by pxa at present but
  53. * should not be used by new boards/CPUs.
  54. */
  55. . = ALIGN(4096);
  56. .mmutable : {
  57. *(.mmutable)
  58. }
  59. /*
  60. * Compiler-generated __bss_start and __bss_end, see arch/arm/lib/bss.c
  61. * __bss_base and __bss_limit are for linker only (overlay ordering)
  62. */
  63. .bss_start __rel_dyn_start (OVERLAY) : {
  64. KEEP(*(.__bss_start));
  65. __bss_base = .;
  66. }
  67. .bss __bss_base (OVERLAY) : {
  68. *(.bss*)
  69. . = ALIGN(4);
  70. __bss_limit = .;
  71. }
  72. .bss_end __bss_limit (OVERLAY) : {
  73. KEEP(*(.__bss_end));
  74. }
  75. /DISCARD/ : { *(.dynsym) }
  76. /DISCARD/ : { *(.dynstr*) }
  77. /DISCARD/ : { *(.dynamic*) }
  78. /DISCARD/ : { *(.plt*) }
  79. /DISCARD/ : { *(.interp*) }
  80. /DISCARD/ : { *(.gnu*) }
  81. /DISCARD/ : { *(.ARM.exidx*) }
  82. /DISCARD/ : { *(.gnu.linkonce.armexidx.*) }
  83. }